Fixing PowerPoint 2008 Web Exports

-- So, I’ve spent the last few days wrestling with a curriculum unit that an outside consultant built. In PowerPoint. On Windows. And which we have been trying to set up in such a way that we can share the interactive document with students. Who are using Macs. And, perhaps, without asking each student to download a ~200MB file to use it.
-- I have learned and grown much in the process. And have discovered that Microsoft PowerPoint 2008 does an execrable job of exporting PowerPoints as web pages (it does an execrable job of doing a lot of other things too, but we can talk about that at another time). Here are the key fixes that I made to the exported web page and supporting files so that the presentation would fundamentally work (all of this was done using regular expressions in TextMate):
 
-- Pick a PowerPoint 2008 web export folder and enter the name of the Links & Sources folder
set theFolder to (choose folder with prompt "Choose which PowerPoint 2008 web export folder to clean:") & "/"
display dialog "What is the (URL Encoded) name of the Links & Sources folder?" default answer "Links%20&%20Sources"
set LinksAndSources to text returned of result
display dialog "What is the title of this presentation?" default answer "PowerPoint Presentation"
set PPTTitle to text returned of result
 
-- I stripped out all of the fancy Javascript calls that PowerPoint inserted as links to navigate from one slide to another. It turns out that a simple HREF to the actual page’s HTML file works (and the JavaScript Does Not.)
set query1 to "(href=\")[^\"]*(slide\\d{4,4}.htm)[^\"]*(\")"
-- 2009-12-02 SDB: Tweaked all replacement strings to use TextWrangler-style grep replacements (\1 instead of $1 in TextMate)
set replace1 to "\\1\\2\\3"
 
-- The export to web page takes all of the already URL-encoded links in the PowerPoint and reencodes them, rendering them useless. I stripped off the second encoding.
set query2 to "(%)25([a-fA-F0-9]{2,2})"
set replace2 to "\\1\\2"
 
-- Finally, because the links were built in Windows and then URL-encoded, all of the Windows-style paths needed to be turned into POSIX paths for use on the web.
set query3 to "%5[cC]"
set replace3 to "/"
 
-- At this point, in an average PowerPoint, most of the damage has been fixed and things more or less work. However, the curriculum unit that we were working with also linked to external Word documents (hence some of the Windows-style path issues above). This meant I had a few more fixes along the way that are worthy of note:
 
-- I replaced the links to Word documents with links to the corresponding PDF files (and script I used generated PDF files with .doc.pdf extensions and I didn’t bother to fix that).
set query4 to "(href=\"[^\"]*docx?)(\")"
set replace4 to "\\1.pdf\\2"
 
-- These links to external documents open in the same frame as the slideshow. Which defeats the purpose of the slideshow being a navigational tool. So I redirected all of the new PDF links to a new window in the browser. As the hyperlinks are broken across two lines in the HTML source code, this took two steps.
 
-- Find (changing the name of Links & Sources folder to the, well... the actual name of the Links & Sources folder):
-- 2009-12-02 SDB: Tweaked \n to \r so that TextWrangler would find the EOL
set query5 to "(href=\"((http://)|(" & LinksAndSources & "))[^\"]*\")\\r"
set replace5 to "\\1"
 
set query6 to "(href=\"((http://)|(" & LinksAndSources & "))[^\"]*\"\\starget=\")_top(\")"
set replace6 to "\\1_blank\\5"
 
tell application "TextWrangler"
 
	-- This is inelegant
	replace query1 using replace1 saving yes searching in theFolder options {search mode:grep, returning results:false}
	replace query2 using replace2 saving yes searching in theFolder options {search mode:grep, returning results:false}
	replace query3 using replace3 saving yes searching in theFolder options {search mode:grep, returning results:false}
	replace query4 using replace4 saving yes searching in theFolder options {search mode:grep, returning results:false}
	replace query5 using replace5 saving yes searching in theFolder options {search mode:grep, returning results:false}
	replace query6 using replace6 saving yes searching in theFolder options {search mode:grep, returning results:false}
 
	-- Some other cleanup kinds of things to make everything nicer (lord knows why PowerPoint 2008 exports this way...)
	replace "<title>PowerPoint Presentation  -  Slide 1</title>" using "<title>" & PPTTitle & "</title>" saving yes searching in theFolder options {search mode:literal, returning results:false}
	replace "<link title=\"Presentation File\" type=\"application/powerpoint\" rel=alternate\\rhref=\"[^\"]*\">\\r" using "" saving yes searching in theFolder options {search mode:grep, returning results:false}
	replace "(if \\( parent.includeNotes \\))" using "parent.includeNotes = false;\\r\\t\\1" saving yes searching in theFolder & "frame.htm" options {search mode:grep, returning results:false}
end tell</link>